Произведение двух чисел делится на 29, если хотя бы один из сомножителей делится на 29.

При вводе чисел можно подсчитывать количество чисел, кратных 29, не считая четырёх последних. Обозначим их n29.

Примечание для проверяющего. Сами числа, кроме четырёх последних, при этом можно не хранить.

Очередное считанное число будем рассматривать как возможный правый элемент искомой пары. Если очередное считанное число делится на 29, то к ответу следует прибавить количество чисел до него, не считая четырёх последних (включая считанное). Если очередное считанное число на 29 не делится, то к ответу следует прибавить n29.

Чтобы построить программу, эффективную по памяти, заметим, что, поскольку при обработке очередного элемента входных данных используются значения, находящиеся на четыре элемента ранее, достаточно хранить только четыре последних элемента или информацию о них. Ниже приведена реализующая описанный алгоритм программа на языке Паскаль (использована версия PascalABC).

Пример 1. Программа на языке Паскаль. Программа эффективна по времени и памяти.

const s = 4; {требуемое расстояние между элементами}
var
    n: longint;
    a: array[1..s] of longint; {хранение последних s значений}
    a_: longint; {очередное значение}
    n29: longint; {количество делящихся на 29 элементов, не считая s последних}
    cnt: longint; {количество искомых пар}
    i, j: longint;
begin
    readln(n); {Ввод первых s чисел}
    for i:=1 to s do
        readln(a[i]); {Ввод остальных значений, подсчет искомых пар}
    cnt := 0;
    n29 := 0;
    for i := s + 1 to n do
    begin
        if a[1] mod 29 = 0 then
            n29 := n29 + 1;
        readln(a_);
        if a_ mod 29 = 0 then
            cnt := cnt + i - s
        else
            cnt := cnt + n29;
{сдвигаем элементы вспомогательного массива влево}
        for j := 1 to s - 1 do
            a[j] := a[j + 1];
        a[s] := a_ {записываем текущий элемент в конец массива}
    end;
    writeln(cnt)
end.

Пример 2. Программа на языке Python. Программа эффективна по времени и памяти.

s = 4
a = [0]*s
n = int(input())
for i in range(s):
    a[i] = int(input())
cnt = 0
n29 = 0
for i in range(s, n):
    k = i % s
    if a[k] % 29 == 0:
        n29 = n29 + 1
    a_ = int(input())
    if a_ % 29 == 0:
        cnt = cnt + i - s + 1
    else:
        cnt = cnt + n29
    a[i % s] = a_
print(cnt)

Пример 3. Программа на языке С++. Программа эффективна по времени и памяти.

    #include 
    using namespace std;
    int main()
    {
        int s = 4; //требуемое расстояние между элементами
        int n;
        int n1 = 0, n2 = 0, n3 = 0, n4 = 0;
        //хранение последних s счетчиков
        int a_; // очередное значение
        int cnt; // количество искомых пар
        cin >> n;
        cnt = 0;
        for (int i = 0; i < n; ++i)
        {
            cin >> a_; // считано очередное значение
            if (i >= s)
            {
                if (a_ % 29 == 0)
                    cnt += i - s + 1;
                else
                    cnt += n4;
            }
            //сдвигаем элементы счетчиков
            n4 = n3;
            n3 = n2;
            n2 = n1;
            //обновляем счетчик кратных 29
            if (a_ % 29 == 0)
                n1 += 1;
        }
        cout << cnt;
        return 0;
    }

Пример 4. Программа на языке Паскаль. Программа эффективна по времени и неэффективна по памяти.

const s = 4; {требуемое расстояние между элементами}
var
    n: longint;
    a: array[1..1000] of longint;
    n29: longint;
    {количество делящихся на 29 элементов, не считая s последних}
    cnt: longint; {количество искомых пар}
    i, j: longint;
begin
    readln(n);
    {Ввод первых s чисел}
    for i:=1 to s do
        readln(a[i]);
    {Ввод остальных значений, подсчет искомых пар}
    cnt := 0;
    n29 := 0;
    for i := s + 1 to n do
    begin
        readln(a[i]);
        if a[i - s] mod 29 = 0 then
            n29 := n29 + 1;
        if a[i] mod 29 = 0 then
            cnt := cnt + i - s
        else
            cnt := cnt + n29;
    end;
    writeln(cnt)
end.